Основы автоматизации на SLAX
Fundamentals
- SLAX is based on XPath 1.0 and XSLT 1.0.
- Переменные задаются только 1 раз и дальше уже нет возможности их изменить.
- The “Node-Set” variable data-type is from XPath. Используется оператор :=.
var $my-ns-var := {
<interface> {
<name> "ge-0/0/0"; }
<interface> {
<name> "ge-0/0/1";
- The “Result Tree Fragment” (RTF) может хранить в себе как строку, так и блок XML данных. Используется оператор =.
var $my-ns-var = {
<interface> {
<name> "ge-0/0/0"; }
<interface> {
<name> "ge-0/0/1";
- Шаблон по умолчанию вернет RTF, но с помощью использования := можео заставить его вернуть node-set.
- Разница между node-set и RTF - в знаке назначения переменной.
- Context Processing. Насколько я поняла, можно использовать (.) как current context. Пример:
var $my := {
<interface> {
<name> "ge-0/0/0";
<descr> 'interface 1';
}
<interface> {
<name> "ge-0/0/1";
<descr> 'interface 2';}}
match / {
<op-script-results> {
for-each ($my/interface) {
<output> ./name;
<output> ./descr; }}
SLAX Script File Structure
Для просмотра в XML формате используем:
blair> show configuration | display xml
Comments: - можно располагать хоть где в коде.
- (/*) - open-comment
- (*/) - close-comment
- At the top: В скриптах в начале обязательно добавляется:
version 1.0; ns junos = "http://xml.juniper.net/junos/*/junos"; ns xnm = "http://xml.juniper.net/xnm/1.1/xnm"; ns jcs = "http://xml.juniper.net/junos/commit-scripts/1.0"; Import "../import/junos.xsl";
после junos.xsl можно добавить любые свои файлы, написанные на SLAX, XSLT или их комбинации.
- param - не изменяемые, нужно таким образом задать параметры командной строки.
param $interface; param $mtu-size = 2000;
можно задать переменную, например mtu-size, и если юзер не будет указывать напрямую значение нужного параметра, то будет использоваться то значение, которое указано через param.
- $arguments - глобальная переменная, обеспечивает полезную информацию из CLI. Предоставляет доступные аргументы в command-line;
- $event-definition - глобальная переменная, задающая условия для выполнения скрипта.
- main template - концептуальное начало скрипта. Шаблон, который матчит первый элемент из input XML document (source tree), даже если он пустой.
Для op script - выглядит так:
match / {
<op-script-results> {
/* your code goes here */
Для event script - выглядит так:
match / {
<event-script-results> {
/* your code goes here */
Для commit script - выглядит так:
match configuration {
/* your code goes here */
Variables
Простые типы данных
Начало: var $xxx
Нельзя использовать в начале juno, jcs, xnm, slax. Нельзя: $arguments, $event-definition
Можно использовать : в названии переменной. Удобно, при создании библиотек, и когда скрипт будет вложен в скрипт.
Переменную можно объявить:
- глобально - только эти переменные могут быть "перезаписаны" дальше в коде, лучше этого не допускать.
- в шаблоне/функции
- внутри программного control-block (for-each and the if/then/else)
Типы данных: строка (string), число (number), логическая (boolean), node-set.
- Boolean: true() and false(). boolean() - функция переделывает выражение в логические. 0 = false, non-0 = true и т.д. Empty RTF coverts to true.
- Numbers: целые или дробные (.)
- Strings: " " или ' '. string() - функция превращает аргумент в строку.
- Result Tree Fragments: можем использовать как script output, обработать как строку, или конвертировать в node-set. При объявлении переменной такого типа нельзя заканчивать ; после }. Каждый шаблон возвращает RTF.
- Node-set: =RTF, отличие от RTF - при присвоении переменной значения используем :=. XPath expressions работают только с node-sets. Также отличие - к node-set можно применять операторы сравнения. ( | ) - оператор для создания комбинации node-sets.
Пример: for-each( ($primary-colors | $fav-colors)/color ) {...
Сложные структуры данных
- массивы - нет массивов как таковых, но можно использовать node-set XPath expressions особым образом.
Элементы массива начинаются с 1, а не с 0.
Пример задания массива:
var $interfaces := {
<int> "ge-0/0/0";
<int> "ge-0/0/1";
<int> "ge-0/0/2";
<int> "ge-0/0/3";
<int> "ge-1/0/1";
<int> "ge-1/0/2";
<int> "ge-1/0/3";
<int> "ge-1/0/4"; }
match / {
<op-script-results> {
<output> "interface 5 = " _ $interfaces/int[5] _ "\n";
<output> "all interfaces:\n";
for-each ($interfaces/int) {
<output> .; }}}
Вывод:
blair> op arrays interface 5 = ge-1/0/1 all interfaces: ge-0/0/0 ge-0/0/1 ge-0/0/2 ge-0/0/3 ge-1/0/1 ge-1/0/2 ge-1/0/3 ge-1/0/4
- хэши - (аналог Dictionary в Python) нет хешей как таковых, но можно использовать node-set XPath expressions особым образом.
Пример: hash1 - где key - status - аттрибут данных (значение элемента int), $hash2 - key - mtu - элемент данных (элемент int, такой же как и int).
var $hash1 := {
<int name = "ge-0/0/0"> "down";
<int name = "ae2"> "up"; }
var $hash2 := {
<int> {
<name> "ge-0/0/0";
<mtu> "1500"; }
<int> {
<name> "ae8";
<mtu> "2000"; }}
match / {
<op-script-results> {
/*Interface status in $hash1*/
<output> "ge-0/0/0 is " _ $hash1/int[@name == 'ge-0/0/0'];
<output> "ae2 is " _ $hash1/int[@name == 'ae2'];
/*Interface MTU from $hash2*/
<output> "MTU ae8 = " _ $hash2/int[name=='ae8']/mtu; }}
Вывод:
blair> op hash ge-0/0/0 is down ae2 is up MTU ae8 = 2000
Еще один метод использования hash - XSLT <xsl:key> top-level element and key() function.
key - используются для индексирования node внутри XML.
<xsl:key> top-level element - содержит name, node index, ссылку на нужный node.
key () - функция, которая "достает" нужный node. Содержит имя key и желаемое значение key.
/* Define <xsl:key> elements */
<xsl:key name="protocol" match="route-table/rt" use="rt-entry/protocol-name">;
<xsl:key name="next-hop" match="route-table/rt" use="rt-entry/nh/via">;
var $match-protocol = "Static"; /* we want to match on "static" routes */
var $match-interface= "ge-0/0/0.60"; /*we want to match on routes via interface ge-0/0/0.60 */
match /
{ <op-script-results> {
var $results = jcs:invoke("get-route-information");
/* Change current node to the $results XML document */
for-each( $results ) {
/* Display all static routes */
<output> $match-protocol _ " routes: ";
for-each( key( "protocol", $match-protocol ) ) {
<output> rt-destination;
}
/* Display all routes with next-hop of ge-0/0/0.60 */
<output> "Next-hop " _ $match-interface _ ": ";
for-each( key( "next-hop", $match-interface ) ) {
<output> rt-destination;
}
Вывод: blair> op route-info Static routes: 6.6.6.6/32 Next-hop ge-0/0/0.60: 10.200.86.5/32 10.200.86.6/32 10.200.86.7/32 192.168.86.4/30 192.168.86.8/30 192.168.86.28/30 192.168.86.44/30
И последний способ:
var $protocol = 'Static';
match / {
<op-script-results> {
var $results = jcs:invoke("get-route-information");
for-each( $results ) {
<output> $protocol _ " routes: ";
for-each( .//rt-entry[protocol-name = $protocol] ) {
<output> ../rt-destination; }}}}
Специальные переменные
- Общие:
- $product - name of the Junos device
- $user - user, запускающий скрипт
- $hostname - hostname
- $script - скрипт, который запускаем
- $localtime - время, когда был запущен скрипт. Вид: Fri Jan 7 14:07:33 2011
- $localtime-iso - 2011-01-08 03:38:57 UTC
- op scripts:
- $param - глобальная переменная, значение которой можно поменять с помощью argument - если в command line задаем какое-то другое значение для param, то будет использоваться новое заданное. Если в command line не задаем никакое, то используется то значение, которое определено в спринте... Лучше посмотреть в примере ниже, станет все понятно...
- $argument - особая переменная, кот предоставляет доступные аргументы в command-line;
param $protocol = 'Static';
var $arguments = {
<argument> {
<name> "protocol";
<description> 'Chouse your favorite protocol!'; }}
match / {
<op-script-results> {
var $results = jcs:invoke("get-route-information");
for-each( $results ) {
<output> $protocol _ " routes: ";
for-each( .//rt-entry[protocol-name = $protocol] ) {
<output> ../rt-destination; }}}}
Вывод:
blair> op route Static routes: 10.20.0.0/16 10.21.0.0/16 10.22.0.0/16 10.23.0.0/16 blair> op route ? Possible completions: <[Enter]> Execute this command <name> Argument name detail Display detailed output protocol Chouse your favorite protocol! | Pipe through a command blair> op route protocol Local Local routes: 192.168.86.9/32 192.168.86.18/32 192.168.86.26/32 192.168.86.50/32 192.168.88.1/32
- event scripts
- $event-definition - определяет условия для срабатывания скрипта
var $event-definition = {
<event-options> {
<generate-event> {
<name> "every-hour";
<time-interval> "3600";
}
<policy> {
<name> "check-var-utilization";
<events> "every-hour";
<then> {
<event-script> {
<name> "check-var-utilization.slax"; }}}}}
- $junos-context - содержит информацию об устройстве, но для каждых типов скриптов имеет свой набор параметров.
If/then/else
Можно использовать следующим образом. В таком случае если переменная $mytree должно обрабатываться как $node-set, то ставим =, если как простая переменная, то можно :=. Структура, пример:
var $this = 10;
var $that = 5;
var $mytree := {
if ( $this < $that ) {
<tree> "Pine";
<tree> "Birch"; }
else if ( $this = $that ) {
<tree> "Spruce";
<tree> "Fir"; }
else {
<tree> "Gooseberry";
<tree> "Juniper"; }}
match / {
<op-script-results> {
for-each ( $mytree/tree) {
<output> .; }}} - (.) стала указателем для каждой node в node-set,
blair> op if-then Gooseberry Juniper
For-each
Структура:
for-each( <xpath-expresssion> ) {
... }
Пример:
match / {
<op-script-results> {
var $ge_ints := {
var $results = jcs:invoke("get-interface-information");
for-each ($results/physical-interface[starts-with(name, "ge-")]/logical-interface) {
var $ifd = .;
<interface> {
<name> $ifd/name;
<ip-addr> $ifd/address-family/interface-address/ifa-destination; }}}
for-each ($ge_ints/interface) {
<output> "Interface " _ ./name _ " has IP addr of " _ ./ip-addr; }}}
Вывод:
blair> op for-each
Interface ge-0/0/0.60 has IP addr of 192.168.86.8/30
Interface ge-0/0/0.80 has IP addr of 192.168.86.48/30
Interface ge-0/0/0.100 has IP addr of 192.168.86.16/30
Interface ge-0/0/0.110 has IP addr of 192.168.86.24/30
Interface ge-0/0/0.32767 has IP addr of
Interface ge-0/0/1.0 has IP addr of 192.168.88.0/30
- $ge_ints будет содержать node-set вида, который мы создаем с помощью for-each:
<interface 1> <name 1> <ip-addr 1> <interface 2> <name 2> <ip-addr 2> ...
- $results - будет выглядеть следующим образом:
blair> show interfaces | display xml <rpc-reply xmlns:junos="http://xml.juniper.net/junos/12.1X47/junos"> <interface-information xmlns="http://xml.juniper.net/junos/12.1X47/junos-interface" junos:style="normal"> <physical-interface> <name>ge-0/0/0</name> <admin-status junos:format="Enabled">up</admin-status> <oper-status>up</oper-status> <local-index>134</local-index> <snmp-index>507</snmp-index> <link-level-type>Flexible-Ethernet</link-level-type> <mtu>1518</mtu> ...
- $ifd - путь = $results/physical-interface[starts-with(name, "ge-")]/logical-interface.
© Наталия Бобкова 2014—2022